##############################################################################
# Fried Script by Jason Fried <cshrc@jasonfried.info>           Skel Distro  #
# INFO avalible at http://jasonfried.info/friedscript                        #
##############################################################################

#Bare Bones Path
set path = ( /bin /usr/bin /usr/local/bin )

set distloc='http://jasonfried.info/friedscript/'
set distfile='cshrc.tar.gz'
set gettool='NONE'

alias cshrcupdate       'cd ~ && rm -f ${distfile};${gettool} ${distloc}${distfile} && gzip -dc ${distfile} | tar xf - && rm -f ${distfile} && reload'

if ( -X fetch ) then
    set gettool='fetch'
else if ( -X wget ) then
    set gettool='wget -q'
else if ( -X curl ) then
    set gettool='curl -O'
else if ( -X perl ) then
    if ({ (perl -e "use LWP::Simple" >& /dev/null)  }) then
	alias phttpcat 'perl -MLWP::Simple -e "exit is_error getprint shift"'
	alias pwget   'phttpcat \!* > `basename \!*`'
	if ("$gettool" == "NONE") then
	    set gettool = 'pwget' #Make of the new alias
	endif
    endif
endif

alias reload	source ~/.cshrc

if ("$gettool" != "NONE") then
    echo "Grabing a fresh copy of the Friedcshrc Script...."
    echo "Remember Place your local settings in .cshrc.local"
    cshrcupdate
else
    echo "No HTTP/FTP fetch tool found..."
    echo "set gettool='toolname -args' and type 'cshrcupdate'"
endif